xmlns = "http://relaxng.org/ns/structure/1.0"
  
Keywords         = element|attribute|list|mixed|parent|empty|text|notAllowed|external|grammar|div|include|start|inherit|string|token
Identifier       = <NCNAME>&~<Keywords>
CName            = <NCNAME>:<NCNAME>
  
Ls1              = (<CHAR>&[^\"])*
Ls2              = (<CHAR>&[^\'])*
Ls3              = <CHAR>*&~.*"\"\"\"".*
Ls4              = <CHAR>*&~.*"'''".*

topLevel : "default" __ "namespace" _ "=" _ [literal l] [grammarContents gs] = <grammar ns=[literal l]> [grammarContents gs] </>

identifier : [Identifier i] = _ [Identifier i] _
           : "\\" [NCNAME n] = [NCNAME n]

literal : "\"" [Ls1 l] "\""         = [Ls1 l]
       >: "'" [Ls2 l] "'"           = [Ls2 l]
       >: "\"\"\"" [Ls3 l] "\"\"\"" = [Ls3 l]
       >: "'''" [Ls4 l] "'''"       = [Ls4 l]

grammarContents : __ [grammarContent g] [grammarContents gs] = [grammarContent g] [grammarContents gs]
                :                                            =

bpattern : "element" __ [nameClass n] _ "{" _ [pattern p] _ "}"            = <element> [nameClass n] [pattern p] </>
         : "attribute" __ [nameClass n] _ "{" _ [pattern p] _ "}"          = <attribute> [nameClass n] [pattern p] </>
         : "list" _ "{" _ [pattern p] _ "}"                                = <list> [pattern p] </>
         : "mixed" _ "{" _ [pattern p] _ "}"                               = <mixed> [pattern p] </>
         : [identifier i]                                                  = <ref name=[identifier i]> </>
         : "parent" __ [identifier i]                                      = <parentRef name=[identifier i]> </>
         : "empty"                                                         = <empty> </>
         : "text"                                                          = <text> </>
         : [datatypeValue dv]                                              = <value> [datatypeValue dv] </>
         : [dataTypeName dn] __ [datatypeValue dv]                         = <value type=[dataTypeName dn]> [datatypeValue dv] </>
         : [dataTypeName dn] _ "{" _ [params ps] _ "}" _ [exceptPattern e] = <data type=[dataTypeName dn]> [params ps] [exceptPattern e] </>
         : "notAllowed"                                                    = <notAllowed> </>
         : "external" __ [anyURILiteral a]                                 = <externalRef href=[anyURILiteral a]> </>
         : "grammar" _ "{" _ [grammarContents gs] _ "}"                    = <grammar> [grammarContents gs] </>
         : "(" _ [gpattern g] _ "|" _ [crestpattern c] _ ")"               = <choice> [gpattern g] [crestpattern c] </>
         : "(" _ [ipattern i] _ "," _ [grestpattern g] _ ")"               = <group> [ipattern i] [grestpattern g] </>
         : "(" _ [upattern u] _ "\&" _ [irestpattern i] _ ")"              = <interleave> [upattern u] [irestpattern i] </>

upattern : [bpattern b] _ "?" = <optional> [bpattern b] </>
         : [bpattern b] _ "*" = <zeroOrMore> [bpattern b] </>
         : [bpattern b] _ "+" = <oneOrMore> [bpattern b] </>
         : [bpattern b]       = [bpattern b]

irestpattern : [upattern u] _ "\&" _ [irestpattern i] = [upattern u] [irestpattern i]
             : [upattern u]                           = [upattern u]

ipattern : [upattern u] _ "\&" _ [irestpattern i] = <interleave> [upattern u] [irestpattern i] </>
         : [upattern u]                           = [upattern u]

grestpattern : [ipattern i] _ "," _ [grestpattern g] = [ipattern i] [grestpattern g]
             : [ipattern i]                          = [ipattern i]

gpattern : [ipattern i] _ "," _ [grestpattern g] = <group> [ipattern i] [grestpattern g] </>
         : [ipattern i]                          = [ipattern i]

crestpattern : [gpattern g] _ "|" _ [crestpattern c] = [gpattern g] [crestpattern c]
             : [gpattern g]                          = [gpattern g]

cpattern : [gpattern g] _ "|" _ [crestpattern c] = <choice> [gpattern g] [crestpattern c] </>
         : [gpattern g]                          = [gpattern g]

pattern : [cpattern c]  = [cpattern c]

param : [identifier i] _ "=" _ [literal l] = <param name=[identifier i]> [literal l] </>

params : [param p] _ [params ps] = [param p] [params ps]
       :                         =
         
exceptPattern : "-" [pattern p] = <except> [pattern p] </>
              :                 =

grammarContent : [start s]                                                          = [start s]
               : [define d]                                                         = [define d]
               : "div" _ "{" _ [grammarContents gs] _ "}"                           = <div> [grammarContents gs] </>
               : "include" __ [anyURILiteral a] _ "{" _ [includeContents ics] _ "}" = <include href=[anyURILiteral a]> [includeContents ics] </>
               : "include" __ [anyURILiteral a]                                     = <include href=[anyURILiteral a]> </>

includeContent : [define d]                                = [define d]
               : [start s]                                 = [start s]
               : "div" _ "{" _ [includeContents ics] _ "}" = <div> [includeContents ics] </>

includeContents : [includeContent ic] _ [includeContents ics] = [includeContent ic] [includeContents ics]
                :                                             =

start : "start" _ "=" _ [pattern p]   = <start> [pattern p] </>
      : "start" _ "|=" _ [pattern p]  = <start combine="choice"> [pattern p] </>
      : "start" _ "\&=" _ [pattern p] = <start combine="interleave"> [pattern p] </>

define : [identifier i] _ "=" _ [pattern p]   = <define name=[identifier i]> [pattern p] </>
       : [identifier i] _ "|=" _ [pattern p]  = <define name=[identifier i] combine="choice"> [pattern p] </>
       : [identifier i] _ "\&=" _ [pattern p] = <define name=[identifier i] combine="interleave"> [pattern p] </>

nameClass : [simpleNameClass s]                           = [simpleNameClass s]
          : [simpleNameClass s] _ "|" _ [restNameClass n] = <choice> [simpleNameClass s] [restNameClass n] </>

restNameClass : [simpleNameClass s]                           = [simpleNameClass s]
              : [simpleNameClass s] _ "|" _ [restNameClass r] = [simpleNameClass s] [restNameClass r]

simpleNameClass : [identifier i]                         = <name> [identifier i] </>
                : [NCNAME n]                             = <name> _ [NCNAME n] _ </>
                : [NCNAME ns] ":" [NCNAME n]             = <name ns=[NCNAME ns]> _ [NCNAME n] _ </>
                : "inherit" _ [exceptNameClass e]        = <nsName> [exceptNameClass e] </>
                : [NCNAME ns] ":*" _ [exceptNameClass e] = <nsName ns=[NCNAME ns]> [exceptNameClass e] </>
                : "*" [exceptNameClass e]                = <anyName> [exceptNameClass e] </>

exceptNameClass : "-" _ [nameClass n] = <except> [nameClass n] </>
                :                     =

dataTypeName : [CName c] = [CName c]
             : "string"  = "string"
             : "token"   = "token"

datatypeValue : [literal l] = [literal l]

anyURILiteral : [literal l] = [literal l]