xmlns = "http://bibtexml.sf.net/"

ABSTRACT = [Aa][Bb][Ss][Tt][Rr][Aa][Cc][Tt]
ADDRESS = [Aa][Dd][Dd][Rr][Ee][Ss][Ss]
AFFILIATION = [Aa][Ff][Ff][Ii][Ll][Ii][Aa][Tt][Ii][Oo][Nn]
ANNOTATE = [Aa][Nn][Nn][Oo][Tt][Aa][Tt][Ee]
ARTICLE = [Aa][Rr][Tt][Ii][Cc][Ll][Ee]
AUTHOR = [Aa][Uu][Tt][Hh][Oo][Rr]
BOOK = [Bb][Oo][Oo][Kk]
BOOKLET = [Bb][Oo][Oo][Kk][Ll][Ee][Tt]
BOOKTITLE = [Bb][Oo][Oo][Kk][Tt][Ii][Tt][Ll][Ee]
CATEGORY = [Cc][Aa][Tt][Ee][Gg][Oo][Rr][Yy]
CHAPTER = [Cc][Hh][Aa][Pp][Tt][Ee][Rr]
CONTENTS = [Cc][Oo][Nn][Tt][Ee][Nn][Tt][Ss]
COPYRIGHT = [Cc][Oo][Pp][Yy][Rr][Ii][Gg][Hh][Tt]
CROSSREF = [Cc][Rr][Oo][Ss][Ss][Rr][Ee][Ff]
EDITION = [Ee][Dd][Ii][Tt][Ii][Oo][Nn]
EDITOR = [Ee][Dd][Ii][Tt][Oo][Rr]
HOWPUBLISHED = [Hh][Oo][Ww][Pp][Uu][Bb][Ll][Ii][Ss][Hh][Ee][Dd]
INBOOK = [In][Nn][Bb][Oo][Oo][Kk]
INCOLLECTION = [Ii][Nn][Cc][Oo][Ll][Ll][Ee][Cc][Tt][Ii][Oo][Nn]
INPROCEEDINGS = [Ii][Nn][Pp][Rr][Oo][Cc][Ee][Ee][Dd][Ii][Nn][Gg][Ss]
INSTITUTION = [Ii][Nn][Ss][Tt][Ii][Tt][Uu][Tt][Ii][Oo][Nn]
ISBN = [Ii][Ss][Bb][Nn]
ISSN = [Ii][Ss][Ss][Nn]
JOURNAL = [Jj][Oo][Uu][Rr][Nn][Aa][Ll]
KEY = [Kk][Ee][Yy]
KEYWORDS = [Kk][Ee][Yy][Ww][Oo][Rr][Dd][Ss]
LANGUAGE = [Ll][Aa][Nn][Gg][Uu][Aa][Gg][Ee]
LCCN = [Ll][Cc][Cc][Nn]
LOCATION = [Ll][Oo][Cc][Aa][Tt][Ii][Oo][Nn]
MANUAL = [Mm][Aa][Nn][Uu][Aa][Ll]
MASTERSTHESIS = [Mm][Aa][Ss][Tt][Ee][Rr][Ss][Tt][Hh][Ee][Ss][Ii][Ss]
MISC = [Mm][Ii][Ss][Cc]
MONTH = [Mm][Oo][Nn][Tt][Hh]
MRNUMBER = [Mm][Rr][Nn][Uu][Mm][Bb][Ee][Rr]
NOTE = [Nn][Oo][Tt][Ee]
NUMBER = [Nn][Uu][Mm][Bb][Ee][Rr]
ORGANIZATION = [Oo][Rr][Gg][Aa][Nn][Ii][Zz][Aa][Tt][Ii][Oo][Nn]
PAGES = [Pp][Aa][Gg][Ee][Ss]
PHDTHESIS = [Pp][Hh][Dd][Tt][Hh][Ee][Ss][Ii][Ss]
PRICE = [Pp][Rr][Ii][Cc][Ee]
PROCEEDINGS = [Pp][Rr][Oo][Cc][Ee][Ee][Dd][Ii][Nn][Gg][Ss]
PUBLISHER = [Pp][Uu][Bb][Ll][Ii][Ss][Hh][Ee][Rr]
SCHOOL = [Ss][Cc][Hh][Oo][Oo][Ll]
SERIES = [Ss][Ee][Rr][Ii][Ee][Ss]
SIZE = [Ss][Ii][Zz][Ee]
TECHREPORT = [Tt][Ee][Cc][Hh][Rr][Ee][Pp][Oo][Rr][Tt]
TITLE = [Tt][Ii][Tt][Ll][Ee]
TYPE = [Tt][Yy][Pp][Ee]
UNPUBLISHED = [Uu][Nn][Pp][Uu][Bb][Ll][Ii][Ss][Hh][Ee][Dd]
URL = [Uu][Rr][Ll]
VOLUME = [Vv][Oo][Ll][Uu][Mm][Ee]
YEAR = [Yy][Ee][Aa][Rr]

JAN = [Jj][Aa][Nn]
FEB = [Ff][Ee][Bb]
MAR = [Mm][Aa][Rr]
APR = [Aa][Pp][Rr]
MAY = [Mm][Aa][Yy]
JUN = [Jj][Uu][Nn]
JUL = [Jj][Uu][Ll]
AUG = [Aa][Uu][Gg]
SEP = [Ss][Ee][Pp]
OCT = [Oo][Cc][Tt]
NOV = [Nn][Oo][Vv]
DEC = [Dd][Ee][Cc]

ID = <CHAR>*&[^ \n\t\r,}"]+ (MAX)
CHARR = <CHAR>&[^"{}~\n]
INT = [0-9]+ (MAX)
WS = [ \t\n\r]* (MAX)

PART = <CHAR>+&([^",{}\&<>~ \n\t]+)&~([Aa][Nn][Dd])

AND = [Aa][Nn][Dd]

file : [entries es] = <file> [entries es] </>

rhs : [INT i] = [INT i]
   >: "{" [chars s] "}" = [chars s]
   >: "\"" [chars s] "\"" = [chars s]

chars : [char c] [chars s] = [char c] [chars s]
      : =

char : [CHARR c] = [CHARR c]
     : "~" = "&#160;"
     : "{" [chars s] "}" = "{" [chars s] "}"
    >: "\n" = " "

parts : [PART p] = [PART p]
     >: "{" [PART p] "}" = [PART p]
      : "\&" = "&amp;"
      : "<" = "&lt;"
      : ">" = "&gt;"
      : "~" = "&#160;"
      : "\n" = " "
      : [PART p] __ [parts ps] = [PART p] __ [parts ps]
      : _ = _

name : [parts ps] = [parts ps]
//   : [parts last] _ "," _ [parts first] = [parts first] [parts last]

authors : [name n] = <author> [name n] </>
        : [name n] __ [AND] __ [authors as] = <author> [name n] </> [authors as]

editors : [name n] = <editor> [name n] </>
        : [name n] __ [AND] __ [editors es] = <editor> [name n] </> [editors es]
          

entries : [entry e] [WS "\n"] [entries es] = [entry e] [entries es]
        : =

entry : [article e] = [article e]
      : [book e] = [book e]
      : [booklet e] = [booklet e]
      : [manual e] = [manual e]
      : [techreport e] = [techreport e]
      : [mastersthesis e] = [mastersthesis e]
      : [phdthesis e] = [phdthesis e]
      : [inbook e] = [inbook e]
      : [incollection e] = [incollection e]
      : [proceedings e] = [proceedings e]
      : [inproceedings e] = [inproceedings e]
      : [unpublished e] = [unpublished e]
      : [misc e] = [misc e]

article : "@" [ARTICLE] _ "{" _ [ID id] _ "," _ [articlefields fs] _ "}" =
          <entry id=[ID id]>
            <article>
               [articlefields fs]
            </>
          </>

articlefields :& [author author] 
                [title title] 
                [journal journal] 
                [year year] 
                [volume volume] 
                [number number] 
                [pagesopt pagesopt] 
                [month month] 
                [noteopt noteopt] 
                [common common] =
                  [author author]
                  [title title]
                  [journal journal]
                  [year year]
                  [volume volume]
                  [number number]
                  [pagesopt pagesopt]
                  [month month]
                  [noteopt noteopt]
                  [common common]

book : "@" [BOOK] _ "{" _ [ID id] _ "," _ [bookfields fs] _ "}" =
       <entry id=[ID id]>
         <book>
           [bookfields fs]
         </>
       </>

bookfields :& [authoreditor authoreditor] 
             [title title] 
             [publisher publisher]
             [year year] 
             [volumenumber volumenumber] 
             [series series]
             [address address]
             [edition edition]
             [month month]
             [noteopt noteopt]
             [common common] =
               [authoreditor authoreditor]
               [title title]
               [publisher publisher]
               [year year]
               [volumenumber volumenumber]
               [series series]
               [address address]
               [edition edition]
               [month month]
               [noteopt noteopt]
               [common common]

authoreditor : [author author] = [author author]
             : [editor editor] = [editor editor]

booklet : "@" [BOOKLET] _ "{" _ [ID id] _ "," _ [bookletfields fs] _ "}" =
          <entry id=[ID id]>
            <booklet>
              [bookletfields fs]
            </>
          </>

bookletfields :& [authoropt authoropt] 
                [title title] 
                [howpublished howpublished] 
                [address address] 
                [month month] 
                [year year] 
                [noteopt noteopt] 
                [common common] =
                  [authoropt authoropt]
                  [title title]
                  [howpublished howpublished]
                  [address address]
                  [month month]
                  [year year]
                  [noteopt noteopt]
                  [common common]

manual : "@" [MANUAL] _ "{" _ [ID id] _ "," _ [manualfields fs] _ "}" =
         <entry id=[ID id]>
           <manual>
             [manualfields fs]
           </>
         </>

manualfields :& [authoropt authoropt] 
               [title title] 
               [organization organization] 
               [address address] 
               [edition edition] 
               [month month] 
               [yearopt yearopt] 
               [noteopt noteopt] 
               [common common] =
                 [authoropt authoropt]
                 [title title]
                 [organization organization]
                 [address address]
                 [edition edition]
                 [month month]
                 [yearopt yearopt]
                 [noteopt noteopt]
                [common common]
 
techreport : "@" [TECHREPORT] _ "{" _ [ID id] _ "," _ [techreportfields fs] _ "}" =
             <entry id=[ID id]>
               <techreport>
                 [techreportfields fs]
               </>
             </> 

techreportfields :& [author author] 
                   [title title] 
                   [institution institution] 
                   [year year] 
                   [type type] 
                   [number number] 
                   [address address] 
                   [month month] 
                   [noteopt noteopt] 
                   [common common] =
                     [author author]
                     [title title] 
                     [institution institution]
                     [year year]
                     [type type]
                     [number number]
                     [address address]
                     [month month]
                     [noteopt noteopt]
                     [common common]
                   

mastersthesis : "@" [MASTERSTHESIS] _ "{" _ [ID id] _ "," _ [thesisfields fs] _ "}" =
                <entry id=[ID id]>
                  <mastersthesis>
                    [thesisfields fs]
                  </>
                </>

thesisfields :& [author author] 
               [title title] 
               [school school] 
               [year year] 
               [type type] 
               [address address] 
               [month month] 
               [noteopt noteopt] 
               [common common] =
                 [author author]
                 [title title]
                 [school school]
                 [year year]
                 [type type]
                 [address address]
                 [month month]
                 [noteopt noteopt]
                 [common common]

phdthesis : "@" [PHDTHESIS] _ "{" _ [ID id] _ "," _ [thesisfields fs] _ "}" =
                <entry id=[ID id]>
                  <phdthesis>
                    [thesisfields fs]
                  </>
                </>

inbook : "@" [INBOOK] _ "{" _ [ID id] _ "," _ [inbookfields fs] _ "}" =
         <entry id=[ID id]>
           <inbook>
             [inbookfields fs]
           </>
         </>

inbookfields :& [authoreditor authoreditor] 
               [title title]
               [chapterpages chapterpages]
               [publisher publisher] 
               [year year] 
               [volumenumber volumenumber] 
               [series series] 
               [type type] 
               [address address] 
               [edition edition]                
               [month month] 
               [noteopt noteopt] 
               [common common] =
                 [authoreditor authoreditor]
                 [title title]
                 [chapterpages chapterpages]
                 [publisher publisher]
                 [year year]
                 [volumenumber volumenumber]
                 [series series]
                 [type type]
                 [address address]
                 [edition edition]
                 [month month]
                 [noteopt noteopt]
                 [common common]

chapterpages : [chapter chapter] = [chapter chapter]
             : [chapter chapter] _ [pages pages] = [chapter chapter] [pages pages]
             : [pages pages] = [pages pages]

volumenumber : [volume volume] = [volume volume]
             : [number number] = [number number]

incollection : "@" [INCOLLECTION] _ "{" _ [ID id] _ "," _ [incollectionfields fs] _ "}" =
               <entry id=[ID id]>
                 <incollection>
                   [incollectionfields fs]
                 </>
               </>

incollectionfields :& [author author] 
                     [title title] 
                     [booktitle booktitle] 
                     [publisher publisher] 
                     [year year] 
                     [editoropt editoropt] 
                     [volumenumber volumenumber] 
                     [series series] 
                     [type type] 
                     [chapteropt chapteropt] 
                     [pagesopt pagesopt] 
                     [address address] 
                     [edition edition] 
                     [month month] 
                     [noteopt noteopt] 
                     [common common] =
                       [author author]
                       [title title]
                       [booktitle booktitle]
                       [publisher publisher]
                       [year year]
                       [editoropt editoropt]
                       [volumenumber volumenumber]
                       [series series]
                       [type type]
                       [chapteropt chapteropt]
                       [pagesopt pagesopt]
                       [address address]
                       [edition edition]
                       [month month]
                       [noteopt noteopt]
                       [common common]

proceedings : "@" [PROCEEDINGS] _ "{" _ [ID id] _ "," _ [proceedingsfields fs] _ "}" =
               <entry id=[ID id]>
                 <proceedings>
                   [proceedingsfields fs]
                 </>
               </>

proceedingsfields :& [editoropt editoropt] 
                    [titleopt titleopt] 
                    [yearopt yearopt] 
                    [volumenumber volumenumber] 
                    [series series] 
                    [address address] 
                    [month month] 
                    [organization organization] 
                    [publisheropt publisheropt] 
                    [noteopt noteopt] 
                    [common common] =
                      [editoropt editoropt]
                      [titleopt titleopt]
                      [yearopt yearopt]
                      [volumenumber volumenumber]
                      [series series]
                      [address address]
                      [month month]
                      [organization organization]
                      [publisheropt publisheropt]
                      [noteopt noteopt]
                      [common common]

inproceedings : "@" [INPROCEEDINGS] _ "{" _ [ID id] _ "," _ [inproceedingsfields fs] _ "}" =
                 <entry id=[ID id]>
                   <inproceedings>
                     [inproceedingsfields fs]
                   </>
                 </>

inproceedingsfields :& [author author] 
                      [title title] 
                      [booktitle booktitle] 
                      [year year] 
                      [editoropt editoropt] 
                      [volumenumber volumenumber] 
                      [series series] 
                      [pagesopt pagesopt] 
                      [address address] 
                      [month month] 
                      [organization organization] 
                      [publisheropt publisheropt] 
                      [noteopt noteopt] 
                      [common common] =
                        [author author]
                        [title title]
                        [booktitle booktitle]
                        [year year]
                        [editoropt editoropt]
                        [volumenumber volumenumber]
                        [series series] 
                        [pagesopt pagesopt]
                        [address address]
                        [month month]
                        [organization organization]
                        [publisheropt publisheropt]
                        [noteopt noteopt]  
                        [common common]

unpublished : "@" [UNPUBLISHED] _ "{" _ [ID id] _ "," _ [unpublishedfields fs] _ "}" =
              <entry id=[ID id]>
                <unpublished>
                  [unpublishedfields fs]
                </>
              </>

unpublishedfields :& [author author] 
                    [title title] 
                    [note note] 
                    [month month] 
                    [yearopt yearopt] =
                      [author author]
                      [title title]
                      [note note]
                      [month month]
                      [yearopt yearopt]

misc : "@" [MISC] _ "{" _ [ID id] _ "," _ [miscfields fs] _ "}" =
       <entry id=[ID id]>
         <misc>
           [miscfields fs]
         </>
       </>

miscfields :& [authoropt authoropt] 
             [titleopt titleopt] 
             [howpublished howpublished] 
             [month month] 
             [yearopt yearopt] 
             [noteopt noteopt]
             [common common] =
               [authoropt authoropt]
               [titleopt titleopt]
               [howpublished howpublished]
               [month month]
               [yearopt yearopt]
               [noteopt noteopt]
               [common common]

common : [key key] 
         [annotate annotate] 
         [crossref crossref] 
         [user user] =
           [key key] 
           [annotate annotate] 
           [crossref crossref] 
           [user user] 

user : [abstract abstract] 
       [affiliation affiliation] 
       [contents contents] 
       [copyright copyright] 
       [isbnissn isbnissn] 
       [keywords keywords] 
       [language language] 
       [lccn lccn] 
       [location location] 
       [mrnumber mrnumber] 
       [price price] 
       [size size] 
       [url url] 
       [category category] =
         [abstract abstract] 
         [affiliation affiliation] 
         [contents contents] 
         [copyright copyright] 
         [isbnissn isbnissn] 
         [keywords keywords] 
         [language language] 
         [lccn lccn] 
         [location location] 
         [mrnumber mrnumber] 
         [price price] 
         [size size] 
         [url url] 
         [category category] 

author : [AUTHOR] _ "=" _ "{" [authors as] "}" _ "," _ = [authors as] 
      >: [AUTHOR] _ "=" _ "\"" [authors as] "\"" _ "," _   = [authors as] 

authoropt : [author author] = [author author]
          : =

editor : [EDITOR] _ "=" _ "{" [editors es] "}" _ "," _ = [editors es] 
      >: [EDITOR] _ "=" _ "\"" [editors es] "\"" _ "," _   = [editors es] 

editoropt : [editor editor] = [editor editor]
          : =

title : [TITLE] _ "=" _ [rhs r] _ "," _ = <title> [rhs r] </>

titleopt : [title title] = [title title]
         : =

booktitle : [BOOKTITLE] _ "=" _ [rhs r] _ "," _ = <booktitle> [rhs r] </>

journal : [JOURNAL] _ "=" _ [rhs r] _ "," _ = <journal> [rhs r] </>

year : [YEAR] _ "=" _ [rhs r] _ "," _ = <year> [rhs r] </>

yearopt : [year year] = [year year]
        : =

series : [SERIES] _ "=" _ [rhs r] _ "," _ = <series> [rhs r] </>
       : = 

volume : [VOLUME] _ "=" _ [rhs r] _ "," _ = <volume> [rhs r] </>
       : =

number : [NUMBER] _ "=" _ [rhs r] _ "," _ = <number> [rhs r] </>
       : =

chapter : [CHAPTER] _ "=" _ [rhs r] _ "," _ = <chapter> [rhs r] </>

chapteropt : [chapter chapter] = [chapter chapter]
           : =

pages : [PAGES] _ "=" _ [rhs r] _ "," _ = <pages> [rhs r] </>

pagesopt : [pages pages] = [pages pages]
         : =

month : [MONTH] _ "=" _ [JAN] _ "," _ = <month> "January" </>
      : [MONTH] _ "=" _ [FEB] _ "," _ = <month> "February" </>
      : [MONTH] _ "=" _ [MAR] _ "," _ = <month> "March" </>
      : [MONTH] _ "=" _ [APR] _ "," _ = <month> "April" </>
      : [MONTH] _ "=" _ [MAY] _ "," _ = <month> "May" </>
      : [MONTH] _ "=" _ [JUN] _ "," _ = <month> "June" </>
      : [MONTH] _ "=" _ [JUL] _ "," _ = <month> "July" </>
      : [MONTH] _ "=" _ [AUG] _ "," _ = <month> "August" </>
      : [MONTH] _ "=" _ [SEP] _ "," _ = <month> "September" </>
      : [MONTH] _ "=" _ [OCT] _ "," _ = <month> "October" </>
      : [MONTH] _ "=" _ [NOV] _ "," _ = <month> "November" </>
      : [MONTH] _ "=" _ [DEC] _ "," _ = <month> "December" </>
     >: [MONTH] _ "=" _ [rhs r] _ "," _ = <month> [rhs r] </>
      : =

note : [NOTE] _ "=" _ [rhs r] _ "," _ = <note> [rhs r] </>
      

noteopt : [note note] = [note note]
        : =

publisher : [PUBLISHER] _ "=" _ [rhs r] _ "," _ = <publisher> [rhs r] </>
         

publisheropt : [publisher publisher] = [publisher publisher]
             : =

school : [SCHOOL] _ "=" _ [rhs r] _ "," _ = <school> [rhs r] </>

type : [TYPE] _ "=" _ [rhs r] _ "," _ = <type> [rhs r] </>
     : =

institution : [INSTITUTION] _ "=" _ [rhs r] _ "," _ = <institution> [rhs r] </>
            : =

organization : [ORGANIZATION] _ "=" _ [rhs r] _ "," _ = <organization> [rhs r] </>
             : =

edition : [EDITION] _ "=" _ [rhs r] _ "," _ = <edition> [rhs r] </>
        : =

howpublished : [HOWPUBLISHED] _ "=" _ [rhs r] _ "," _ = <howpublished> [rhs r] </>
             : =

address : [ADDRESS] _ "=" _ [rhs r] _ "," _ = <address> [rhs r] </>
        : =

key : [KEY] _ "=" _ [rhs r] _ "," _ = <key> [rhs r] </>
    : =

annotate : [ANNOTATE] _ "=" _ [rhs r] _ "," _ = <annotate> [rhs r] </>
         : =

crossref : [CROSSREF] _ "=" _ [rhs r] _ "," _ = <crossref> [rhs r] </>
         : =

abstract : [ABSTRACT] _ "=" _ [rhs r] _ "," _ = <abstract> [rhs r] </>
         : =

affiliation : [AFFILIATION] _ "=" _ [rhs r] _ "," _ = <affiliation> [rhs r] </>
            : =

contents : [CONTENTS] _ "=" _ [rhs r] _ "," _ = <contents> [rhs r] </>
         : =

copyright : [COPYRIGHT] _ "=" _ [rhs r] _ "," _ = <copyright> [rhs r] </>
          : =

isbnissn : [ISBN] _ "=" _ [rhs r] _ "," _ = <isbn> [rhs r] </>
         : [ISSN] _ "=" _ [rhs r] _ "," _ = <issn> [rhs r] </>
         : =

keywords : [KEYWORDS] _ "=" _ [rhs r] _ "," _ = <keywords> [rhs r] </>
          : =

language : [LANGUAGE] _ "=" _ [rhs r] _ "," _ = <language> [rhs r] </>
         : =

lccn : [LCCN] _ "=" _ [rhs r] _ "," _ = <lccn> [rhs r] </>
     : =

location : [LOCATION] _ "=" _ [rhs r] _ "," _ = <location> [rhs r] </>
         : =

mrnumber : [MRNUMBER] _ "=" _ [rhs r] _ "," _ = <mrnumber> [rhs r] </>
         : =

price : [PRICE] _ "=" _ [rhs r] _ "," _ = <price> [rhs r] </>
      : =

size : [SIZE] _ "=" _ [rhs r] _ "," _ = <size> [rhs r] </>
     : =

url : [URL] _ "=" _ [rhs r] _ "," _ = <url> [rhs r] </>
    : =

category : [CATEGORY] _ "=" _ [rhs r] _ "," _ = <category> [rhs r] </>
         : =