syntax <floatconst> pi ::= {
  3.1415927
}

syntax <regexp> plus ( <regexp R> ) ::= {
  concat(<R>,star(<R>))
}

syntax <regexp> optional ( <regexp R> ) ::= {
  union("", <R>)
}

syntax <regexp> charcomplement ( <charconst C> ) ::= {
  intersection(anything,complement(range(<C>,<C>)))
}

syntax <stm> maybe <stm S> ::= {
  if (random(2)==1) <S>
}

/*
syntax <stm> repeat <stm S> until ( <exp E> ) ; ::= {
  {
    <S>
    while (!<E>) <S>
  }
}
*/

syntax <stm> repeat <stm S> until ( <exp E> ) ; ::= {
  {
    bool first = true;
    while (first || !<E>) {
      <S>
      first = false;
    }
  }
}

syntax <stm> do <stm S> while ( <exp E> ) ; ::= {
  {
    bool first = true;
    while (first || <E>) {
      <S>
      first = false;
    }
  }
}

syntax <stm> forever <stm S> ::= {
  repeat <S> until (false);
}

syntax <stm> loop ( <exp E> ) times <stm S> ::= {
  {
    int n;

    n = <E>;
    while (n>0) {
      <S>
      n--;
    }
  }
}

/*
syntax <stm> for ( <exp E1> ; <exp E2> ; <exp E3> ) <stm S> ::= {
  {
    <E1>;
    while (<E2>) {
      <S>
      <E3>;
    }
  }
}
*/

syntax <exp> MINTIME ::= {
  time(1970,01,01,00,00,00)
}

syntax <exp> MAXTIME ::= {
  time(2038,01,19,03,14,07)
}

syntax <stm> sendemail ( <exp To> , <exp From> , <exp Subject> , <exp Content> ) ::= {
  sendmail(relation { tuple { `name = "To", `value = <To> },
		      tuple { `name = "From", `value = <From> },
		      tuple { `name = "Reply-To", `value = <From> },
		      tuple { `name = "Errors-To", `value = <From> },
		      tuple { `name = "Subject", `value = <Subject> }}, <Content>);
}

syntax <stm> sendhtml ( <exp To> , <exp From> , <exp Subject> , <exp Content> ) ::= {
  sendmail(relation { tuple { `name = "To", `value = <To> },
                      tuple { `name = "From", `value = <From> },
		      tuple { `name = "Reply-To", `value = <From> },
		      tuple { `name = "Errors-To", `value = <From> },
                      tuple { `name = "Content-Type", `value = "text/html" },
                      tuple { `name = "Subject", `value = <Subject> }}, <Content>);
}

syntax <exp> spawn <id Ses> ( <exp_list args> ) ::= {
  post (url <Ses>(<args>))
}

syntax <exp> setYear ( <exp t> , <exp y> ) ::= {
  time(<y>, getMonth(<t>), getDay(<t>), getHour(<t>), getMinute(<t>), getSecond(<t>) )
}

syntax <exp> setMonth ( <exp t> , <exp m> ) ::= {
  time(getYear(<t>), <m>, getDay(<t>), getHour(<t>), getMinute(<t>), getSecond(<t>))
}

syntax <exp> setDay ( <exp t> , <exp d> ) ::= {
  time(getYear(<t>), getMonth(<t>), <d>, getHour(<t>), getMinute(<t>), getSecond(<t>))
}

syntax <exp> setHour ( <exp t> , <exp h> ) ::= {
  time(getYear(<t>), getMonth(<t>), getDay(<t>), <h>, getMinute(<t>), getSecond(<t>))
}

syntax <exp> setMinute ( <exp t> , <exp m> ) ::= {
  time(getYear(<t>), getMonth(<t>), getDay(<t>), getHour(<t>), <m>, getSecond(<t>))
}

syntax <exp> setSecond ( <exp t> , <exp s> ) ::= {
  time(getYear(<t>), getMonth(<t>), getDay(<t>), getHour(<t>), getMinute(<t>), <s>)
}

/* ------------- backward compatibility macros --------------- */

syntax <toplevel_list> resource <id I> ; ::= {
  lock <I>~Lock;
}

syntax <stm> reader (<id R>) <stm S> ::= {
  read (<R>~Lock) <S>
}

syntax <stm> writer (<id R>) <stm S> ::= {
  write (<R>~Lock) <S>
}

syntax <toplevel_list> protected <type T> <id I> ; ::= {
  <T> <I>;
  lock <I>~Lock;
}